********************************
* Copyright:                   *
* Vishay Intertechnology, Inc. *
********************************
*May 19, 2014
*ECN S14-1053, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1016CX D1 G1 S1 D2 G2 S2
x1  D1 G1 S1 Si1016CX_N
x2  D2 G2 S2 Si1016CX_P
.ENDS Si1016CX
*N-CH
.SUBCKT Si1016CX_N D G S
x1  D G S Si1016CX_N_mos
x2  G S   Si1016CX_N_esd
.ENDS Si1016CX_N
.SUBCKT Si1016CX_N_mos D G S 
M1 3 GX S S NMOS W= 40266u L= 0.3u 
M2 S GX S D PMOS W= 40266u L= 0.3u
R1 D 3 2.74e-01 3.215e-03 2.184e-06 
CGS GX S 2.469e-11 
CGD GX D 5.623e-12 
RG G GY 12.2
RTCV 100 S 1e6 3.96e-04 -6.441e-06 
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD 40266u 
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 1.7e-8 
+ RS = 0 KP = 4.304e-05 NSUB = 1.236e+17 
+ KAPPA = 1.000e-06 NFS = 8.000e+09 
+ LD = 0 IS = 0 TPG = 1 CAPOP = 12 ) 
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 1.7e-8 
+NSUB = 4.577e+16 IS = 0 TPG = -1 CAPOP = 12 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 4.847e-08 TREF = 25 BV = 21 
+RS = 1.042e-02 N = 1.697e+00 IS = 1.000e-06 
+EG = 1.215e+00 XTI = -7.303e+00 TRS = 1.000e-05 
+CJO = 4.508e-10 VJ = 5.751e-01 M = 3.659e-01 ) 
.ENDS Si1016CX_N_mos
.subckt Si1016CX_N_esd 1 2 
r1 1 9 9.422e+06 -7.063e-03 
d1 9 2 dleak M=1 
.MODEL dleak d (IS = 4.652e-10 XTI = 5.768e+02 EG = 1.17 
+ TREF = 25 TCV = 0 N = 4.541e+01 BV = 50) 
r2 1 10 2.712e+02 -4.115e-03 
d3 11 10 dout M= 0.514 
d4 11 12 dout M= 0.514 
d5 13 12 dout M= 0.575 
d6 13 2 dout M= 0.575 
.MODEL dout D (IS = 1.763e-10 XTI = 1.433e+01 EG = 1.17 
+ TREF = 25 TCV = -3.285e-03 N = 2.898e+00 BV = 6.560e+00 ) 
.ends Si1016CX_N_esd 
*P-CH
.SUBCKT Si1016CX_P D G S
x1  D G S Si1016CX_P_mos
x2  G S   Si1016CX_P_esd
.ENDS Si1016CX_P
.SUBCKT Si1016CX_P_mos D G S 
M1 3 GX S S PMOS W= 55000u L= 0.3u 
M2 S GX S D NMOS W= 55000u L= 0.5u
R1 D 3 3.82e-01 2.685e-03 3.008e-06 
CGS GX S 1.997e-12
CGD GX D 3.707e-12 
RG G GY 12 
RTCV 100 S 1e6 -1.0598e-06 -3.109e-07 
ETCV GY GX 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD D S DBD 55000u 
**************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 1.7e-8 
+ RS = 0 KP = 6.394e-06 NSUB = 1.544e+14 
+ KAPPA = 3.613e-05 NFS = 1.000e+12 
+ LD = 0 IS = 0 TPG = -1 CAPOP = 12 ) 
*************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 1.7e-8 
+NSUB = 7.3e+16 IS = 0 TPG = -1 CAPOP = 12 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 2.000e-08 TREF = 25 BV = 21 
+RS = 7.015e-03 N = 1.950e+00 IS = 1.000e-06 
+EG = 1.190e+00 XTI = -3.492e+00 TRS = 2.182e-04 
+CJO = 3.524e-10 VJ = 3.000e-01 M = 4.244e-01 )   
.ENDS Si1016CX_P_mos
.subckt Si1016CX_P_esd 1 2 
r1 1 9 4.284e+05 -2.641e-02 
d1 2 9 dleak 
.MODEL dleak d (IS = 49.565e-11 XTI = 4.200e+02 EG = 1.17 
+ TREF = 25 TCV = 0 N = 4.2950e+01 BV = 50) 
r2 1 10 1.0968e+01 7.000e-05 
d3 11 10 dout 
d4 11 2 dout 
.MODEL dout D (IS = 2.032e-12 XTI = -2.337e+02 EG = 1.17 
+ TREF = 25 TCV = 9.519e-03 N = 48.40e-01 BV = 1.0616e+01 
+ TLEV = 1) 
.ends Si1016CX_P_esd 